Bermain Outseal dkk: 3. Kirim Terima Serial

Setelah di halaman sebelumnya, kita membuat Serial Monitor hanya bekerja menampilkan data, maka di halaman ini, kita membuat agar Serial Monitor bisa digunakan untuk mengirimkan data. Dengan memasukkan dan mengirimkan data lewat Serial Monitor, memudahkan kita untuk mendapatkan lebih banyak informasi dan memungkinkan lebih banyak kontrol dibandingkan dengan alat input lainnya.

Agar berkaitan dengan tema blog ini, yaitu "berkawan" dengan Outseal, maka di sini akan ditunjukkan bagaimana membuat ke-6 hal berikut ini (Kirim & Terima) dengan Serial Monitor:

Meminta (baca) data Coil Outseal dari Serial Monitor
Meminta (baca) data Input Diskrit Outseal dari Serial Monitor
Meminta (baca) data Input Register Outseal dari Serial Monitor
Meminta (baca) data Holding Register Outseal dari Serial Monitor
Mengubah (tulis) data Coil Outseal dari Serial Monitor
Mengubah (tulis) data Holding Register Outseal dari Serial Monitor

Untuk bisa melakukan ke-6 hal di atas, berikut ini hal-hal yang perlu diketahui:

1. Format Permintaan Data

Seperti telah dituliskan di halaman sebelumnya, ada 4 data yang diperlukan dalam komunikasi dengan protokol Modbus, yaitu:

No ID Slave
Kode fungsi
Alamat awal data
Jumlah data/Nilai data

Sedangkan kode fungsi yang diperlukan dapat dilihat dari tabel berikut ini:

Tabel 1. Kode Fungsi

Catatan:

Untuk data no. 4, apabila kode fungsinya 1 - 4, maka isinya adalah jumlah data yang akan dibaca. Apabila kode fungsinya 5 - 16, maka isinya adalah nilai data yang akan dituliskan.

2. Rangkaian Simulasi

Agar bisa menunjukkan hasilnya, dan memudahkan pembuatannya, maka saya menggunakan software Proteus, dengan rangkaian seperti gambar berikut, yang dapat digunakan untuk men-simulasikan ke-6 hal di atas.

Gambar 1. Rangkaian untuk penerapan 6 hal dalam Kirim Terima Serial menggunakan sambungan RS485 antara Master (Arduino Nano) dengan 2 Slave (Outseal Nano dan Outseal Mega)

Catatan Perbaikan Gambar Skematik: kaki T.12 di Outseal Mega seharusnya tidak terhubung ke kaki PE6 (8), tetapi harusnya terhubung ke kaki PG0 (33), hal itu yang menyebabkan mengapa ketika Switch T12 ditekan, tidak membuat output LED U12 menyala.

File Proteus gambar rangkaian di atas dapat diunduh di bagian bawah dari halaman ini.

3. Contoh Program

Program di sini hanya sebagai contoh, karena tentunya ada banyak alternatif program untuk membuat ke-6 hal di atas. Silahkan rekan-rekan bisa memberikan masukan, komentar atau kritik atas contoh program yang ada di halaman ini.

3.1 Contoh Ladder Diagram Outseal Nano (Slave 1)

Berikut ini contoh Ladder Diagram untuk Outseal Nano sebagai Slave1, yang dapat digunakan untuk menunjukkan penerapan dari ke-6 hal di atas. Jangan lupa sebelum menekan tombol Test (kompilasi program), atur di jendela Settings: Hardware = Nano V5, Baudrate = 9600, Alamat Modbus (ID Slave) = 1. Ladder Diagram Outseal Nano ini dapat diunduh di bagian bawah dari halaman ini.

Gambar 2. Ladder Diagram Outseal Nano, Settings = Nano V5, Baudrate = 9600, Alamat modbus = 1

3.2 Contoh Ladder Diagram Outseal Mega (Slave 2)

Berikut ini contoh Ladder Diagram untuk Outseal Mega sebagai Slave2, yang dapat digunakan untuk menunjukkan penerapan dari ke-6 hal di atas. Jangan lupa sebelum menekan tombol Test (kompilasi program), atur di jendela Settings: Hardware = Mega V3, Baudrate = 9600, Alamat Modbus (ID Slave) = 2. Ladder Diagram Outseal Mega ini dapat diunduh di bagian bawah dari halaman ini.

Gambar 3. Ladder Diagram Outseal Mega, Settings = Mega V3, Baudrate = 9600, Alamat modbus = 2

3.3 Contoh Program Arduino Nano (Master)

Berikut ini contoh program Arduino Nano sebagai Master. Program Arduino ini dapat diunduh di bagian bawah dari halaman ini. Agar program Arduino ini bisa dikompilasi (Verify atau Compile), jangan lupa untuk memasang library modbus-esp8266. Library modbus-esp8266 ini dapat diunduh di link ini: https://github.com/emelianov/modbus-esp8266/archive/refs/heads/master.zip. File library modbus ini juga saya lampirkan bersama dengan kode program Arduino, dan juga Ladder Diagram, serta file Proteus, di lampiran yang ada di bagian bawah materi ini.

#include <ModbusRTU.h>
#include <SoftwareSerial.h>
SoftwareSerial S(2, 3);
ModbusRTU mb;
String inputString = "";
bool stringComplete = false;
bool case1 = false;
bool case2 = false;
bool case3 = false;
bool case4 = false;
bool case5 = false;
bool case6 = false;
bool coil[20];
bool idis[20];
uint16_t hreg[10];
uint16_t ireg[10];
void setup() {
Serial.begin(9600);
S.begin(9600);
mb.begin(&S);
mb.master();
mb.readCoil(1, 0, coil, 8); //hanya untuk trigger
while (mb.slave()) {
mb.task();
delay(10);
}
delay(1000);
Serial.println("Silahkan ketik data");
Serial.print("> ");
}
void loop() {
if (stringComplete) {
String d1 = getValue(inputString, ',', 0);
String d2 = getValue(inputString, ',', 1);
String d3 = getValue(inputString, ',', 2);
String d4 = getValue(inputString, ',', 3);
uint8_t id = d1.toInt();
uint8_t kode = d2.toInt();
uint16_t alamat = d3.toInt();
uint16_t nilai = d4.toInt();
switch (kode) {
case 1:
mb.readCoil(id, alamat, coil, nilai);
case1 = true;
break;
case 2:
mb.readIsts(id, alamat, idis, nilai);
case2 = true;
break;
case 3:
mb.readHreg(id, alamat, hreg, nilai);
case3 = true;
break;
case 4:
mb.readIreg(id, alamat, ireg, nilai);
case4 = true;
break;
case 5:
mb.writeCoil(id, alamat, nilai > 0);
case5 = true;
break;
case 6:
mb.writeHreg(id, alamat, nilai);
case6 = true;
break;
}
while (mb.slave()) {
mb.task();
delay(10);
}
if (case1) {
Serial.print("= ");
for (int i = 0; i < nilai; i++) {
Serial.print(coil[i]);
}
Serial.println();
case1 = false;
}
if (case2) {
Serial.print("= ");
for (int i = 0; i < nilai; i++) {
Serial.print(idis[i]);
}
Serial.println();
case2 = false;
}
if (case3) {
Serial.print("= ");
for (int i = 0; i < (nilai - 1); i++) {
Serial.print(hreg[i]);
Serial.print(',');
}
Serial.println(hreg[nilai - 1]);
case3 = false;
}
if (case4) {
Serial.print("= ");
for (int i = 0; i < (nilai - 1); i++) {
Serial.print(ireg[i]);
Serial.print(',');
}
Serial.println(ireg[nilai - 1]);
case4 = false;
}
if (case5) {
mb.readCoil(id, alamat, coil, 1);
while (mb.slave()) {
mb.task();
delay(10);
}
Serial.print("= ");
Serial.println(coil[0]);
case5 = false;
}
if (case6) {
mb.readHreg(id, alamat, hreg, 1);
while (mb.slave()) {
mb.task();
delay(10);
}
Serial.print("= ");
Serial.println(hreg[0]);
case6 = false;
}
inputString = "";
stringComplete = false;
Serial.print("> ");
}
}
void serialEvent() {
while (Serial.available()) {
char inChar = (char)Serial.read();
inputString += inChar;
if (inChar == 13) {
stringComplete = true;
}
}
}
String getValue(String data, char separator, int index) {
int found = 0;
int strIndex[] = { 0, -1 };
int maxIndex = data.length() - 1;
for (int i = 0; i <= maxIndex && found <= index; i++) {
if (data.charAt(i) == separator || i == maxIndex) {
found++;
strIndex[0] = strIndex[1] + 1;
strIndex[1] = (i == maxIndex) ? i + 1 : i;
}
}
return found > index ? data.substring(strIndex[0], strIndex[1]) : "";
}

4. Penerapan Program

Setelah rangkaian sudah tersusun, dan masing-masing kode program sudah dimasukkan ke Outseal Nano, Outseal Mega dan Arduino Nano, maka langkah terakhir adalah menjalankan simulasi Proteus. Agar simulasi bisa berjalan dengan baik, ada 3 hal yang perlu dilakukan:

Tekan tombol Run di Proteus.
Tunggu hingga Virtual Terminal menampilkan tulisan "Silahkan ketik data".
Setelah tulisan tersebut muncul, agar apa yang diketik bisa muncul di Serial Monitor, klik/centang pilihan "Echo Typed Characters", seperti ditunjukkan pada gambar berikut.

Gambar 4. Jalankan simulasi, tunggu hingga muncul "Silahkan ketik data", kemudian klik kanan Virtual Terminal tersebut, centang pada pilihan "Echo Typed Characters"

Berikut ini berturut-turut penerapan simulasi pada ke-6 hal di atas.

1. Meminta data Coil dari Serial Monitor

Dengan berdasarkan format permintaan data di atas, maka untuk membaca data Coil yang ada di Outseal Nano dengan ID Slave = 1, di alamat mulai dari 0, sebanyak 8 data (variabel R.1 - R.8), kode permintaannya bisa ditulis di Serial Monitor:

1,1,0,8 (diikuti Enter)