Bermain Outseal dkk: 6. Penampil LCD + Serial + IoT

Aplikasi 6 ini merupakan pengembangan dari Aplikasi 5, di mana selain bisa mengubah data Outseal Nano/Mega lewat komunikasi serial, dan menampilkannya di LCD, juga bisa terhubung dengan layanan Internet of Things, yang dalam contoh di sini menggunakan layanan Arduino IoT Cloud.

Agar lebih mudah, maka rangkaian Outseal Nano dan Outseal Mega akan menggunakan rangkaian yang sama seperti di Aplikasi 5. Hanya di Aplikasi 6 ini, tidak lagi menggunakan Arduino Uno, sebagai gantinya menggunakan ESP8266.

Catatan: Ada 2 tipe ESP8266 yang banyak digunakan, yaitu tipe ESP8266-01 dan tipe ESP8266-12E. Tipe ESP8266-12E ini sering juga disebut NodeMCU. Masing-masing tipe tersebut memiliki kelebihannya sendiri-sendiri. Oya, mungkin ada rekan-rekan yang bertanya, bagaimana kalau menggunakan ESP32 sebagai ganti ESP8266? Wah, ... tentu saja bisa sekali, karena kemampuan ESP32 lebih tinggi daripada ESP8266, hanya saja, harganya lebih mahal 2-3 kali lipat. Untuk cara penggantiannya, saya jelaskan di bagian akhir tulisan ini.

Berikut ini langkah-langkahnya:

1. Mula-mula, akan ditunjukkan simulasi dari aplikasi ini. Setelah simulasi bisa berjalan dengan baik, barulah akan diperlihatkan bagaimana pembuatannya dengan hardware yang riil. Untuk itu, mulai dari simulasi, siapkan rangkaian Proteus berikut ini: (lihat kembali Aplikasi 5, Penampil LCD + Serial).

Gambar 1(a). Rangkaian Outseal Nano dengan komponen ATmega328 sebagai simulasi ESP8266 (File Proteus ini dapat diunduh di bagian akhir tulisan ini dengan nama file OutsealNano_ESP8266.pdsprj)

Gambar 1(b). Rangkaian Outseal Mega dengan komponen ATmega328 sebagai simulasi ESP8266 (File Proteus ini dapat diunduh di bagian akhir tulisan ini dengan nama file OutsealMega_ESP8266.pdsprj)

Catatan: Berhubung Proteus belum menyediakan komponen ESP8266, maka agar dapat disimulasikan, komponen ESP8266 ini direpresentasikan dengan komponen ATmega328. Kemudian agar rangkaian simulasi Proteus ini dapat terhubung dengan Arduino IoT Cloud, maka rekan-rekan harus menyambungkan hardware ESP8266 yang riil ke Port USB di komputer. Antara hardware ESP8266 dengan ATmega328 di Proteus saling berkomunikasi secara serial melalui COMPIM.

2. Setelah rangkaian dibuat, langkah berikutnya adalah memprogram setiap komponen mikrokontroler, berikut ini berturut-turut programnya:

a. Ladder Diagram Outseal Nano (ATmega328p)

Gambar 2(a). Ladder Diagram untuk Outseal Nano

b. Ladder Diagram Outseal Mega (ATmega128)

Gambar 2(b). Ladder Diagram untuk Outseal Mega

c. KodeProgram_SimulasiESP8266:

Catatan: Kode program untuk simulasi ESP8266 ini sama seperti kode program di Aplikasi ke-4, untuk Arduino Uno:

#include <ModbusRTU.h>
#include <Wire.h>
#include <LiquidCrystal_I2C.h>
#include <SoftwareSerial.h>
SoftwareSerial S(3, 2);
LiquidCrystal_I2C lcd(0x27, 16, 2);
ModbusRTU mb;
String inputString = "";
bool stringComplete = false;
bool case1 = false;
bool case2 = false;
bool case3 = false;
bool case4 = false;
bool case5 = false;
bool case6 = false;
bool coil[20];
bool idis[20];
uint16_t hreg[10];
uint16_t ireg[10];
uint16_t cacah;
unsigned long skr = 0;
void setup() {
Serial.begin(9600);
lcd.init();
lcd.backlight();
S.begin(9600);
mb.begin(&S);
mb.master();
mb.readIsts(1, 0, idis, 16); //hanya untuk trigger
while (mb.slave()) {
mb.task();
delay(10);
}
delay(1000);
Serial.println("Silahkan kirim data");
}
void loop() {
if (stringComplete) {
Serial.print("> ");
Serial.print(inputString);
lcd.setCursor(0, 0);
lcd.print("> ");
lcd.setCursor(1, 0);
lcd.print(inputString);
String d1 = getValue(inputString, ',', 0);
String d2 = getValue(inputString, ',', 1);
String d3 = getValue(inputString, ',', 2);
String d4 = getValue(inputString, ',', 3);
uint8_t id = d1.toInt();
uint8_t kode = d2.toInt();
uint16_t alamat = d3.toInt();
uint16_t nilai = d4.toInt();
switch (kode) {
case 1:
mb.readCoil(id, alamat, coil, nilai);
case1 = true;
break;
case 2:
mb.readIsts(id, alamat, idis, nilai);
case2 = true;
break;
case 3:
mb.readHreg(id, alamat, hreg, nilai);
case3 = true;
break;
case 4:
mb.readIreg(id, alamat, ireg, nilai);
case4 = true;
break;
case 5:
mb.writeCoil(id, alamat, nilai < 1);
case5 = true;
break;
case 6:
mb.writeHreg(id, alamat, nilai);
case6 = true;
break;
}
while (mb.slave()) {
mb.task();
delay(10);
}
if (case1) {
Serial.print(" = ");
lcd.setCursor(0, 1);
lcd.print("= ");
lcd.setCursor(1, 1);
for (int i = 0; i < nilai; i++) {
Serial.print(coil[i] ? "0" : "1");
lcd.print(coil[i] ? "0" : "1");
}
Serial.println();
case1 = false;
}
if (case2) {
Serial.print(" = ");
lcd.setCursor(0, 1);
lcd.print("= ");
lcd.setCursor(1, 1);
for (int i = 0; i < nilai; i++) {
Serial.print(idis[i] ? "0" : "1");
lcd.print(idis[i] ? "0" : "1");
}
Serial.println();
case2 = false;
}
if (case3) {
Serial.print(" = ");
lcd.setCursor(0, 1);
lcd.print("= ");
lcd.setCursor(1, 1);
for (int i = 0; i < (nilai - 1); i++) {
Serial.print(hreg[i]);
Serial.print(',');
lcd.print(hreg[i]);
lcd.print(',');
}
Serial.println(hreg[nilai - 1]);
lcd.print(hreg[nilai - 1]);
case3 = false;
}
if (case4) {
Serial.print(" = ");
lcd.setCursor(0, 1);
lcd.print("= ");
lcd.setCursor(1, 1);
for (int i = 0; i < (nilai - 1); i++) {
Serial.print(ireg[i]);
Serial.print(',');
lcd.print(ireg[i]);
lcd.print(',');
}
Serial.println(ireg[nilai - 1]);
lcd.print(ireg[nilai - 1]);
case4 = false;
}
if (case5) {
mb.readCoil(id, alamat, coil, 1);
while (mb.slave()) {
mb.task();
delay(10);
}
Serial.print(" = ");
Serial.println(coil[0] ? "0" : "1");
lcd.setCursor(0, 1);
lcd.print("= ");
lcd.setCursor(1, 1);
lcd.print(coil[0] ? "0" : "1");
case5 = false;
}
if (case6) {
mb.readHreg(id, alamat, hreg, 1);
while (mb.slave()) {
mb.task();
delay(10);
}
Serial.print(" = ");
Serial.println(hreg[0]);
lcd.setCursor(0, 1);
lcd.print("= ");
lcd.setCursor(1, 1);
lcd.print(hreg[0]);
case6 = false;
}
inputString = "";
stringComplete = false;
}
if (millis() - skr > 1000) {
skr = millis();
tampilLCD();
cacah++;
if (cacah > 5) cacah = 0;
}
}
void serialEvent() {
while (Serial.available()) {
char inChar = (char)Serial.read();
inputString += inChar;
if (inChar == 13) {
stringComplete = true;
skr = millis();
}
}
}
String getValue(String data, char separator, int index) {
int found = 0;
int strIndex[] = { 0, -1 };
int maxIndex = data.length() - 1;
for (int i = 0; i <= maxIndex && found <= index; i++) {
if (data.charAt(i) == separator || i == maxIndex) {
found++;
strIndex[0] = strIndex[1] + 1;
strIndex[1] = (i == maxIndex) ? i + 1 : i;
}
}
return found > index ? data.substring(strIndex[0], strIndex[1]) : "";
}
void tampilLCD() {
switch (cacah) {
case 0:
inputString = "1,2,0,8";
stringComplete = true;
break;
case 1:
inputString = "1,2,8,8";
stringComplete = true;
break;
case 2:
inputString = "1,1,0,8";
stringComplete = true;
break;
case 3:
inputString = "1,1,8,8";
stringComplete = true;
break;
case 4:
inputString = "1,4,0,2";
stringComplete = true;
break;
case 5:
inputString = "1,3,0,2";
stringComplete = true;
break;
}
}

d. KodeProgram_HardwareESP8266

Catatan: Kode program untuk hardware ESP8266 ini akan menghubungkan rangkaian di Proteus dengan Arduino IoT Cloud.

#include "arduino_secrets.h"
#include "thingProperties.h"
void setup() {
Serial.begin(9600);
delay(1500);
initProperties();
ArduinoCloud.begin(ArduinoIoTPreferredConnection);
setDebugMessageLevel(2);
ArduinoCloud.printDebugInfo();
}
void loop() {
ArduinoCloud.update();
if (Serial.available() > 0) {
modbus = Serial.readStringUntil('\n');
}
}
void onModbusChange() {
Serial.println(modbus);
}

3. Silahkan meng-upload program di atas, kecuali untuk KodeProgram_HardwareESP8266, jangan di-upload dulu, karena kode program ini memerlukan secret key, yang hanya dibangkitkan ketika membuat Thing di Arduino IoT Cloud. Untuk itu, ikuti langkah-langkah dalam bentuk gambar berikut ini untuk membuat Thing dan Dashboard di Arduino IoT Cloud:

Langkah 1. buka halaman web cloud.arduino.cc, klik Get Started for free

Langkah 2. Klik Sign In apabila sudah memiliki akun, apabila belum, klik Create One

Langkah 3. Isi username atau email dan password, klik Sign In

Langkah 4. Di daftar Menu, klik Things, klik Create Thing

Langkah 5. Di halaman Things, klik Untitled, Rename menjadi Outseal, kemudian klik Add

Langkah 6. Muncul jendela Add variable, isi Name = Modbus, pilih Character String, klik Add Variable

Langkah 7. Klik Select Device

Langkah 8. Klik Set Up New Device

Langkah 9. Pilih Third party device

Langkah 10. Dalam contoh di sini, saya menggunakan NodeMCU ESP8266 (apabila rekan-rekan menggunakan hardware lain, silahkan memilih sesuai tipe hardware tersebut)

Langkah 11. Muncul nama device, klik Next

Langkah 12. Di halaman ini, kode Secret key diberikan, silahkan klik pada download the PDF, kemudian beri centang pada tulisan I saved ..., kemudian klik Continue

Langkah 13. Maka Setup Device telah selesai, klik Done

Langkah 14. Di halaman Thing, terlihat nama Device muncul, hanya statusnya masih Offline, berikutnya, klik tombol Configure

Langkah 15. Isi nama dan password hotspot WiFi, dan isi Secret key dari file PDF yang baru saja diunduh di langkah no. 12 di atas, klik Save

Langkah 16. Setelah Variabel ditambahkan, Device dipilih, dan Network diisi, berikutnya, klik Tab Sketch

Langkah 17. Muncul halaman Sketch, klik pada Open full editor

Langkah 18. Di halaman Web Editor Arduino, hapus program di Tab Outseal_xxx.ino, dan isi dengan KodeProgram_HardwareESP8266 di atas

Langkah 19. Upload program dengan menekan tombol panah ke samping, namun sebelumnya, pastikan Port COM dan Board yang dipilih sudah benar, dengan menekan tombol panah ke bawah di kolom Board, atur hingga ttanda silang pada kolom Board hilang

Catatan: Apabila Port COM tidak muncul, pastikan rekan-rekan menginstal Arduino Create Agent, yang langkah instalasinya bisa dilihat di sini: Install the Arduino Create Agent – Arduino Help Center

Langkah 20. Setelah upload berhasil, klik Monitor untuk mengetahui apakah koneksi ke Arduino IoT Cloud berhasil atau tidak (tanda koneksi berhasil, muncul tulisan "Connected to Arduino IoT Cloud")

Langkah 21. Terlihat status device masih Offline, tulisan "Connected to Arduino IoT Cloud" masih belum muncul

Langkah 22. Berhubung status device masih Offline, maka alternatif solusinya adalah: download Sketch, kemudian upload dengan software Arduino IDE di komputer, klik Sketchbook, klik kanan Sketch yang paling atas, pilih Download Sketch

Langkah 23. Di folder Download, klik kanan file, pilih Extract Here

Langkah 24. Munucl 5 buah file hasil ekstrak, klik 2 kali pada file ino: Outseal..., maka terbuka software IDE Arduino

Langkah 25. Di Tab arduino_secrets.h, isi nama dan password Wi-Fi serta kode secret key

Langkah 26. Setelah secret key terisi, klik Select Board, pilih tipe Board dan Port COM yang sesuai

Langkah 27. Setelah Board dan Port COM dipilih, langkah berikutnya adalah upload program, klik kanan tombol panah ke kanan, tunggu hingga muncul tulisan Done Uploading

Langkah 28. Terlihat proses upload selesai, muncul tulisan Done Uploading

Langkah 29. Buka Serial Monitor, tunggu hingga muncul tulisan "Connected to Arduino IoT Cloud", seperti ditunjukkan pada gambar di atas

Catatan: Apabila tulisan "Connected to Arduino IoT Cloud" masih belum muncul (biasanya masalah ini hanya terjadi pada ESP8266/NodeMCU), maka solusinya adalah downgrade versi library ArduinoIoTCloud ke versi 1.8.0 dan juga Arduino_ConnectionHandler ke versi 0.7.1. Upload program lagi, seharusnya tulisan "Connected to Arduino IoT Cloud" bisa muncul.

Langkah 30. Downgrade library ArduinoIoTCloud ke 1.8.0 dan library Arduino_ConnectionHandler ke 0.7.1

Langkah 31. Setelah tulisan "Connected to Arduino IoT Cloud" muncul, maka status device Online

Langkah 32. Setelah status device Online, langkah selanjutnya buat Dashboard, klik tombol Menu di pojok kiri atas

Langkah 33. Di daftar menu, klik Dashboards, kemudian klik Create Dashbaord

Langkah 34. Di halaman Dashboard, klik tombol Add, klik Tab Things, klik Outseal

Langkah 35. Di jendela daftar variabel, klik Create Widgets

Langkah 36. Muncul widget Messenger di halaman Dashboard

4. Setelah status device Online dan Dashboard selesai dibuat, langkah berikutnya adalah menjalankan simulasi Proteus. Namun sebelum menjalankan simulasi Proteus, perlu diatur dulu komponen COMPIM. Klik 2 kali komponen COMPIM, isi Physical Port dengan COM yang digunakan oleh hardware NodeMCU, dan atur Baud rate = 9600.

Gambar 3. Isi Physical Port di komponen COMPIM dengan COM yang digunakan NodeMCU, dan atur Baud rate = 9600

5. Jalankan rangkaian Outseal Nano di Proteus, dan perhatikan widget Messenger di Arduino IoT Cloud. Seharusnya widget Messenger akan menampilkan data yang sama seperti tampilan Virtual Terminal KIRIM. Ketik di kolom paling bawah widget Messengger, sebagai contoh ketik "1,6,0,900", maka data ini akan muncul di Virtual Terminal TERIMA, dan juga instruksi tersebut akan membuat LED di kaki R.7 menyala sedikit redup (intensitas cahaya maksimum apabila diberi nilai 1000).

Gambar 4. Terlihat komunikasi antara rangkaian Outseal Nano di Proteus dengan widget Messenger di Arduino IoT Cloud

6. Ulangi langkah no. 5 di atas untuk rangkaian Outseal Mega. Seharusnya widget Messenger akan dapat mengirimkan dan menerima data Modbus dari rangkaian Outseal Mega, memonitor kondisi input digital (16 Switch) dan input analog (2 Potensio), serta mengontrol output digital (16 LED) dan analog pwm (2 LED di kaki R.6 dan R.7).

Gambar 5. Terlihat komunikasi antara rangkaian Outseal Mega di Proteus dengan widget Messenger di Arduino IoT Cloud

7. Setelah simulasi berjalan dengan baik, langkah berikutnya adalah mengimplementasikan ke hardware riil. Di sini saya menggunakan Arduino Nano sebagai simulasi Outseal Nano, dan sebuah NodeMCU untuk menghubungkan Arduino Nano tersebut ke Arduino IoT Cloud. Berikut ini gambar pengawatan rangkaiannya:

Gambar 6. Pengawatan rangkaian hardware Outseal Nano (disimulasikan dengan Arduino Nano) dengan Penampil LCD+Serial+Arduino IoT Cloud

8. Untuk rangkaian Gambar 6 di atas, berbeda dengan rangkaian untuk simulasi Gambar 1(a), di mana di rangkaian Gambar 6 ini, sudah tidak lagi menggunakan komponen ATmega328, tetapi komponen tersebut telah dilebur ke dalam NodeMCU. Jadi program NodeMCU untuk rangkaian Gambar 6 ini menggabungkan KodeProgram_SimulasiESP8266 dan KodeProgram_HardwareESP8266. Berikut ini kode program penggabungan tersebut:

KodeProgram_Penggabungan:

#include "arduino_secrets.h"
#include "thingProperties.h"
#include <ModbusRTU.h>
#include <Wire.h>
#include <LiquidCrystal_I2C.h>
#include <SoftwareSerial.h>
SoftwareSerial S(D5, D6);
LiquidCrystal_I2C lcd(0x27, 16, 2);
ModbusRTU mb;
String var = "";
String inputString = "";
bool stringComplete = false;
bool case1 = false;
bool case2 = false;
bool case3 = false;
bool case4 = false;
bool case5 = false;
bool case6 = false;
bool coil[20];
bool idis[20];
uint16_t hreg[10];
uint16_t ireg[10];
uint16_t cacah;
unsigned long skr = 0;
void setup() {
Serial.begin(9600);
lcd.init();
lcd.backlight();
S.begin(9600);
mb.begin(&S);
mb.master();
mb.readIsts(1, 0, idis, 16); //hanya untuk trigger
while (mb.slave()) {
mb.task();
delay(10);
}
delay(1000);
Serial.println("Silahkan kirim data");
delay(1500);
initProperties();
ArduinoCloud.begin(ArduinoIoTPreferredConnection);
setDebugMessageLevel(2);
ArduinoCloud.printDebugInfo();
}
void loop() {
ArduinoCloud.update();
if (stringComplete) {
Serial.print("> ");
Serial.print(inputString);
lcd.setCursor(0, 0);
lcd.print("> ");
lcd.setCursor(1, 0);
lcd.print(inputString);
modbus = "> " + inputString;
String d1 = getValue(inputString, ',', 0);
String d2 = getValue(inputString, ',', 1);
String d3 = getValue(inputString, ',', 2);
String d4 = getValue(inputString, ',', 3);
uint8_t id = d1.toInt();
uint8_t kode = d2.toInt();
uint16_t alamat = d3.toInt();
uint16_t nilai = d4.toInt();
switch (kode) {
case 1:
mb.readCoil(id, alamat, coil, nilai);
case1 = true;
break;
case 2:
mb.readIsts(id, alamat, idis, nilai);
case2 = true;
break;
case 3:
mb.readHreg(id, alamat, hreg, nilai);
case3 = true;
break;
case 4:
mb.readIreg(id, alamat, ireg, nilai);
case4 = true;
break;
case 5:
mb.writeCoil(id, alamat, nilai < 1);
case5 = true;
break;
case 6:
mb.writeHreg(id, alamat, nilai);
case6 = true;
break;
}
while (mb.slave()) {
mb.task();
delay(10);
}
if (case1) {
Serial.print("= ");
lcd.setCursor(0, 1);
lcd.print("= ");
lcd.setCursor(1, 1);
for (int i = 0; i < nilai; i++) {
Serial.print(coil[i] ? "0" : "1");
lcd.print(coil[i] ? "0" : "1");
var = var + String(coil[i] ? "0" : "1");
}
Serial.println();
modbus = "= " + var;
case1 = false;
}
if (case2) {
Serial.print("= ");
lcd.setCursor(0, 1);
lcd.print("= ");
lcd.setCursor(1, 1);
for (int i = 0; i < nilai; i++) {
Serial.print(idis[i] ? "0" : "1");
lcd.print(idis[i] ? "0" : "1");
var = var + String(idis[i] ? "0" : "1");
}
Serial.println();
modbus = "= " + var;
case2 = false;
}
if (case3) {
Serial.print("= ");
lcd.setCursor(0, 1);
lcd.print("= ");
lcd.setCursor(1, 1);
for (int i = 0; i < (nilai - 1); i++) {
Serial.print(hreg[i]);
Serial.print(',');
lcd.print(hreg[i]);
lcd.print(',');
if (i == 0) var = String(hreg[i]);
else var = var + "," + String(hreg[i]);
}
Serial.println(hreg[nilai - 1]);
lcd.print(hreg[nilai - 1]);
modbus = "= " + var + "," + String(hreg[nilai - 1]);
case3 = false;
}
if (case4) {
Serial.print("= ");
lcd.setCursor(0, 1);
lcd.print("= ");
lcd.setCursor(1, 1);
for (int i = 0; i < (nilai - 1); i++) {
Serial.print(ireg[i]);
Serial.print(',');
lcd.print(ireg[i]);
lcd.print(',');
if (i == 0) var = String(ireg[i]);
else var = var + "," + String(ireg[i]);
}
Serial.println(ireg[nilai - 1]);
lcd.print(ireg[nilai - 1]);
modbus = "= " + var + "," + String(ireg[nilai - 1]);
case4 = false;
}
if (case5) {
mb.readCoil(id, alamat, coil, 1);
while (mb.slave()) {
mb.task();
delay(10);
}
Serial.print("= ");
Serial.println(coil[0] ? "0" : "1");
lcd.setCursor(0, 1);
lcd.print("= ");
lcd.setCursor(1, 1);
lcd.print(coil[0] ? "0" : "1");
modbus = "= " + String(coil[0] ? "0" : "1");
case5 = false;
}
if (case6) {
mb.readHreg(id, alamat, hreg, 1);
while (mb.slave()) {
mb.task();
delay(10);
}
Serial.print("= ");
Serial.println(hreg[0]);
lcd.setCursor(0, 1);
lcd.print("= ");
lcd.setCursor(1, 1);
lcd.print(hreg[0]);
modbus = "= " + String(hreg[0]);
case6 = false;
}
var = "";
inputString = "";
stringComplete = false;
}
if (millis() - skr > 5000) {
skr = millis();
tampilLCD();
cacah++;
if (cacah > 3) cacah = 0;
}
}
void onModbusChange() {
inputString = modbus;
stringComplete = true;
skr = millis();
}
void serialEvent() {
while (Serial.available()) {
char inChar = (char)Serial.read();
inputString += inChar;
if (inChar == 13) {
stringComplete = true;
skr = millis();
}
}
}
String getValue(String data, char separator, int index) {
int found = 0;
int strIndex[] = { 0, -1 };
int maxIndex = data.length() - 1;
for (int i = 0; i <= maxIndex && found <= index; i++) {
if (data.charAt(i) == separator || i == maxIndex) {
found++;
strIndex[0] = strIndex[1] + 1;
strIndex[1] = (i == maxIndex) ? i + 1 : i;
}
}
return found > index ? data.substring(strIndex[0], strIndex[1]) : "";
}
void tampilLCD() {
switch (cacah) {
case 0:
inputString = "1,2,0,8";
modbus = inputString;
stringComplete = true;
break;
case 1:
inputString = "1,1,0,8";
modbus = inputString;
stringComplete = true;
break;
case 2:
inputString = "1,4,0,2";
modbus = inputString;
stringComplete = true;
break;
case 3:
inputString = "1,3,0,2";
modbus = inputString;
stringComplete = true;
break;
}
}

Keterangan program:

Secara garis besar, program untuk NodeMCU di atas akan meminta data Modbus ke Outseal setiap 5 detik, mulai dari data Input Diskrit (Switch), kemudian data Coil (Relay), kemudian data Holding Register (LED PWM), kemudian data Input Register (Potensio). Interval waktu 5 detik tersebut dapat diubah ke angka yang lebih besar dengan mengubah angka 5000 di baris instruksi 191. Disarankan diubah ke angka yang lebih besar agar Outseal tidak terlalu sibuk melayani permintaan NodeMCU ini, sehingga dapat menjalankan tugas lain yang lebih penting.
Outseal akan mengirimkan data tersebut ke NodeMCU, dan oleh NodeMCU, data tersebut ditampilkan di LCD I2C dan juga di Serial Monitor, dan kemudian diteruskan ke widget Messenger di Arduino IoT Cloud.
Selain membaca data dari Outseal, NodeMCU juga dapat mengubah data di Outseal, khususnya untuk data Coil (melalui memori internal B - Binary, untuk mengubah kondisi Relay) dan Holding Register (melalui memori internal I - Integer, untuk mengubah intensitas cahaya LED dengan nilai duty cycle pwm: 0 - 1000), yang datanya bisa dimasukkan melalui widget Messenger, dan juga bisa melalui Serial Monitor.
Berhubung sinyal input di Outseal menggunakan konfigurasi Aktif Low, di mana sinyal Low malah bernilai 1, dan sinyal High malah bernilai 0, maka agar logikanya menjadi benar, ditambahkan instruksi pembalikan seperti ini: idis[i] ? "0" : "1";
Berhubung Modul Relay sebagai output menggunakan konfigurasi Aktif Low, di mana nilai 0 membuat Relay ON, dan 1 malah membuat Relay OFF, maka agar logikanya menjadi benar, ditambahkan instruksi pembalikan seperti ini: coil[0] ? "0" : "1";
Begitu pula untuk pengubahan datanya, agar logikanya menjadi benar, pada instruksi writeCoil dilakukan pembalikan dengan isntruksi seperti ini: mb.writeCoil(id, alamat, nilai < 1);
Selain membaca data dari Outseal, NodeMCU juga dapat mengubah data di Outseal, khususnya untuk data Coil (melalui memori internal B - Binary, untuk mengubah kondisi Relay) dan Holding Register (melalui memori internal I - Integer, untuk mengubah intensitas cahaya LED dengan nilai duty cycle pwm: 0 - 1000), yang datanya bisa dimasukkan melalui widget Messenger, dan juga bisa melalui Serial Monitor.
Program di atas bisa digunakan untuk menampilkan data Outseal Nano dan Outseal Mega yang lebih dari 1 (yang terhubung dengan sambungan RS-485), dengan cara mengatur ID sesuai alamat Modbus Slave, yang diisikan pada Settings di Outseal Studio.
Silahkan memperbanyak Case pada void tampilLCD() di baris program 226 - 249, sehingga dapat menampilkan data Modbus yang terdiri dari Coil, Input Diskrit, Input Register, dan Holding Register untuk setiap Outseal yang dihubungkan, yang ditampilkan secara berurutan, mulai dari Case1 ke Case berikutnya. Jumlah Case ini diatur dalam variabel cacah, yang di-nol-kan lagi setelah mencapai maksimum (lihat baris 195).

8. Upload program di atas ke hardware NodeMCU, dan susun rangkaian seperti Gambar 6 di atas. Foto berikut ini menunjukkan hasil penerapan program, di mana terlihat komunikasi antara Outseal dengan Arduino IoT Cloud melalui NodeMCU, yang memperlihatkan tampilan LCD dan tampilan widget Messenger menampilkan hasil yang sama.

Gambar 7. Komunikasi antara rangkaian Outseal dan Arduino IoT Cloud melalui NodeMCU berjalan dengan baik, terlihat tampilan LCD I2C dan widget Messenger di Arduino IoT Cloud menampilkan hasil yang sama

9. Sampai di sini langkah-langkah implementasi Penampil LCD + Serial + IoT untuk Outseal Nano dan Outseal Mega. Untuk memudahkan rekan-rekan dalam mempelajari materi di halaman ini, rekan-rekan bisa mengunduh semua file yang diperlukan dalam pembuatan aplikasi di halaman ini di link berikut ini: https://drive.google.com/file/d/185BWxCiCMW7DwoofT0eVnCMQ99XedaRM/view?usp=sharing

10. Agar lebih jelas, berikut ini video pembuatan Penampil LCD + Serial + IoT yang dibuat mengikuti materi di halaman ini.

Video pembuatan aplikasi Penampil data Outseal di LCD I2C, Serial Monitor dan Arduino IoT Cloud

Catatan: Apabila rekan-rekan menggunakan ESP32 sebagai ganti NodeMCU, maka perhatikan hal berikut ini:

Pastikan saat memilih tipe device di Select Device adalah ESP32, dengan pilihan ESP32 Dev Module.
Untuk ESP32, upload program bisa langsung dari Web Editor Arduino online. Arduino IoT Cloud memberikan dukungan penuh untuk ESP32 ini, sehingga tidak akan terjadi masalah status device tidak bisa Online seperti terjadi pada NodeMCU.
ESP32 memiliki 3 buah Hardware Serial, sehingga tidak memerlukan Software Serial. Untuk itu ubah instruksi pada baris 7 dari KodeProgram_Penggabungan di atas, dari semula SoftwareSerial S(D5,D6); ubah menjadi HardwareSerial S(1);
Berikutnya ubah juga instruksi di baris 29, dari semula S.begin(9600); ubah menjadi S.begin(9600, SERIAL_8N1, 9, 10); di mana kaki 9 adalah RXD dan kaki 10 adalah TXD. Kedua kaki ini dapat diubah sesuai dengan keinginan.
Untuk lebih jelasnya mengenai pengubahan kode program untuk ESP32 ini, silahkan unduh file di langkah no. 9 di atas, dan buka KodeProgram_Penggabungan_ESP32.
Kaki SDA dan SCL di ESP32 secara default adalah kaki 21 (SDA) dan 22 (SCL). Hubungkan kaki SDA dan SCL ini ke LCD I2C.

Catatan: Untuk contoh penggunaan 2 Outseal Nano yang terhubung secara RS485 dan dikontrol serta dimonitor dari Arduino IoT Cloud dapat teman-teman lihat di sini: Bermain Arduino IoT Cloud: Aplikasi#3. Outseal IoT

Bermain Outseal dkk

Pages

6. Penampil LCD + Serial + IoT

2 comments:

Report Abuse